mirror of
https://github.com/trezor/trezor-firmware.git
synced 2024-11-25 08:58:14 +00:00
48 lines
1.5 KiB
ArmAsm
48 lines
1.5 KiB
ArmAsm
.syntax unified
|
|
|
|
.text
|
|
|
|
.global reset_handler
|
|
.type reset_handler, STT_FUNC
|
|
reset_handler:
|
|
// setup environment for subsequent stage of code
|
|
ldr r0, =ccmram_start // r0 - point to beginning of CCMRAM
|
|
ldr r1, =ccmram_end // r1 - point to byte where BOOT_ARGS region starts
|
|
ldr r2, =0 // r2 - the word-sized value to be written
|
|
bl memset_reg
|
|
|
|
ldr r0, =sram_start // r0 - point to beginning of SRAM
|
|
ldr r1, =sram_end // r1 - point to byte after the end of SRAM
|
|
ldr r2, =0 // r2 - the word-sized value to be written
|
|
bl memset_reg
|
|
|
|
// copy data in from flash
|
|
ldr r0, =data_vma // dst addr
|
|
ldr r1, =data_lma // src addr
|
|
ldr r2, =data_size // size in bytes
|
|
bl memcpy
|
|
|
|
// setup the stack protector (see build script "-fstack-protector-all") with an unpredictable value
|
|
bl rng_get
|
|
ldr r1, = __stack_chk_guard
|
|
str r0, [r1]
|
|
|
|
// re-enable exceptions
|
|
// according to "ARM Cortex-M Programming Guide to Memory Barrier Instructions" Application Note 321, section 4.7:
|
|
// "If it is not necessary to ensure that a pended interrupt is recognized immediately before
|
|
// subsequent operations, it is not necessary to insert a memory barrier instruction."
|
|
cpsie f
|
|
|
|
// r11 contains the command passed to bootargs_set()
|
|
// function called when the firmware rebooted to the bootloader
|
|
ldr r0, =g_boot_command_shadow
|
|
str r11, [r0]
|
|
|
|
// enter the application code
|
|
bl main
|
|
|
|
b shutdown_privileged
|
|
|
|
.end
|
|
|