mirror of
https://github.com/trezor/trezor-firmware.git
synced 2024-10-20 23:09:13 +00:00
6257584951
core: Remove dangling module decls
core: Use new Cargo feature resolver, use external MacOS debug info
core: Rust docs improvements
core: Upgrade bindgen
core: Add test target to Rust
ci: build rust sources
build(core): .ARM.exidx.text.__aeabi_ui2f in t1 firmware size
It's an unwind table for softfloat function inserted by rustc, probably
can be removed to save 8 bytes:
599c58db70/link.x.in (L175-L182)
scons: Remove dead code
core: Move Rust target to build/rust
core: Replace extern with a FFI version
core: Add some explanatory Rust comments
core: Use correct path for the Rust lib
core: Remove Buffer::as_mut()
Mutable buffer access needs MP_BUFFER_WRITE flag. TBD in the Protobuf PR.
core: Improve docs for micropython::Buffer
core: Minor Rust docs changes
core: Rewrite trezor_obj_get_ll_checked
core: Fix incorrect doc comment
core: Remove cc from deps
fixup! core: Rewrite trezor_obj_get_ll_checked
core: update safety comments
101 lines
3.0 KiB
Nix
101 lines
3.0 KiB
Nix
{ fullDeps ? false
|
|
, hardwareTest ? false
|
|
}:
|
|
|
|
let
|
|
mozillaOverlay = import (builtins.fetchTarball {
|
|
url = "https://github.com/mozilla/nixpkgs-mozilla/archive/8c007b60731c07dd7a052cce508de3bb1ae849b4.tar.gz";
|
|
sha256 = "1zybp62zz0h077zm2zmqs2wcg3whg6jqaah9hcl1gv4x8af4zhs6";
|
|
});
|
|
# the last successful build of nixpkgs-unstable as of 2021-03-25
|
|
nixpkgs = import (builtins.fetchTarball {
|
|
url = "https://github.com/NixOS/nixpkgs/archive/c0e881852006b132236cbf0301bd1939bb50867e.tar.gz";
|
|
sha256 = "0fy7z7yxk5n7yslsvx5cyc6h21qwi4bhxf3awhirniszlbvaazy2";
|
|
}) { overlays = [ mozillaOverlay ]; };
|
|
moneroTests = nixpkgs.fetchurl {
|
|
url = "https://github.com/ph4r05/monero/releases/download/v0.17.1.9-tests/trezor_tests";
|
|
sha256 = "410bc4ff2ff1edc65e17f15b549bd1bf8a3776cf67abdea86aed52cf4bce8d9d";
|
|
};
|
|
moneroTestsPatched = nixpkgs.runCommandCC "monero_trezor_tests" {} ''
|
|
cp ${moneroTests} $out
|
|
chmod +wx $out
|
|
${nixpkgs.patchelf}/bin/patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" "$out"
|
|
chmod -w $out
|
|
'';
|
|
rustNightly = (nixpkgs.rustChannelOf { date = "2021-03-29"; channel = "nightly"; }).rust.override {
|
|
targets = [
|
|
"x86_64-unknown-linux-gnu" # emulator
|
|
"thumbv7em-none-eabihf" # TT
|
|
"thumbv7em-none-eabi" # T1
|
|
];
|
|
};
|
|
in
|
|
with nixpkgs;
|
|
stdenv.mkDerivation ({
|
|
name = "trezor-firmware-env";
|
|
buildInputs = lib.optionals fullDeps [
|
|
# install other python versions for tox testing
|
|
# NOTE: running e.g. "python3" in the shell runs the first version in the following list,
|
|
# and poetry uses the default version (currently 3.8)
|
|
python38
|
|
python39
|
|
python37
|
|
python36
|
|
] ++ [
|
|
SDL2
|
|
SDL2_image
|
|
autoflake
|
|
bash
|
|
check
|
|
clang-tools
|
|
clang
|
|
editorconfig-checker
|
|
gcc
|
|
gcc-arm-embedded
|
|
git
|
|
gitAndTools.git-subrepo
|
|
gnumake
|
|
graphviz
|
|
libffi
|
|
libjpeg
|
|
libusb1
|
|
openssl
|
|
pkgconfig
|
|
poetry
|
|
protobuf3_6
|
|
rustfmt
|
|
rustNightly
|
|
wget
|
|
zlib
|
|
] ++ lib.optionals (!stdenv.isDarwin) [
|
|
procps
|
|
valgrind
|
|
] ++ lib.optionals (stdenv.isDarwin) [
|
|
darwin.apple_sdk.frameworks.CoreAudio
|
|
darwin.apple_sdk.frameworks.AudioToolbox
|
|
darwin.apple_sdk.frameworks.ForceFeedback
|
|
darwin.apple_sdk.frameworks.CoreVideo
|
|
darwin.apple_sdk.frameworks.Cocoa
|
|
darwin.apple_sdk.frameworks.Carbon
|
|
darwin.apple_sdk.frameworks.IOKit
|
|
darwin.apple_sdk.frameworks.QuartzCore
|
|
darwin.apple_sdk.frameworks.Metal
|
|
darwin.libobjc
|
|
libiconv
|
|
] ++ lib.optionals hardwareTest [
|
|
uhubctl
|
|
ffmpeg
|
|
dejavu_fonts
|
|
];
|
|
LD_LIBRARY_PATH = "${libffi}/lib:${libjpeg.out}/lib:${libusb1}/lib:${libressl.out}/lib";
|
|
NIX_ENFORCE_PURITY = 0;
|
|
|
|
# Fix bdist-wheel problem by setting source date epoch to a more recent date
|
|
SOURCE_DATE_EPOCH = 1600000000;
|
|
|
|
# Used by rust bindgen
|
|
LIBCLANG_PATH = "${llvmPackages.libclang}/lib";
|
|
} // (lib.optionalAttrs fullDeps) {
|
|
TREZOR_MONERO_TESTS_PATH = moneroTestsPatched;
|
|
})
|